Gmsh. Четырехугольные, прямоугольные и регулярные треугольные сетки

По умолчанию Gmsh строит симплициальные сетки (треугольные, тетраэдральные). Однако он (я считаю, что Gmsh - это он, триангулятор, несмотря на все его CAD, Solver и Postprocessing способности) может сделать разбиение и другими элементами. Вот их список (взят из описания формата выходного файла сетки):

• 3-узловой треугольник
• 4-узловой четырехугольник
• 4-узловой тетраэдр
• 8-узловой шестигранник (гексаэдр)
• 6-узловая призма
• 5-узловая пирамида
• а также элементы 2-го, 3-го, 4-го и 5-го порядков (не для всех типов элементов)

Сегодня мы рассмотрим способы построения четырехугольной (и как частный случай, прямоугольной) сетки.

Рекомбинирование
Gmsh дает возможность рекомбинировать треугольную сетку таким образом, чтобы получить четырехугольные элементы. Вообще говоря, рекомбинирование не даст вам в общем случае только четырехугольную сетку. Рассмотрим простой пример.
Определим в Gmsh'е квадрат со стороной 1:

1.    cl = 0.1;
2.    Point(1) = {0, 0, 0, cl};
3.    Point(2) = {1, 0, 0, cl};
4.    Point(3) = {1, 1, 0, cl};
5.    Point(4) = {0, 1, 0, cl};
6.    Line(1) = {1, 2};
7.    Line(2) = {2, 3};
8.    Line(3) = {3, 4};
9.    Line(4) = {4, 1};
10.    Line Loop(5) = {1, 2, 3, 4};
11.    Plane Surface(1) = {5};

Полученная сетка имеет вид:

Чтобы получить рекомбинированную сетку, можно, как обычно, пойти двумя путями: через окно меню и через .geo файл. И, как обычно, мы рассматриваем только второй вариант, т.к., во-первых, интерфейс Gmsh'а довольно сильно меняется с выходом новой версии, поэтому приведенные здесь скриншоты меню через некоторое время станут неактуальны (а скрипт .geo файла работает всегда); а во-вторых, вам и самим будет интересно полазить в меню, так что не буду лишать вас удовольствия открытия новых кнопочек. Могу еще добавить чисто субъективно - задавать параметры разбиения удобнее в .geo файле. Но вы, конечно, можете со мной не согласиться.
Для построения рекомбинированной сетки в конец .geo файла достаточно добавить строку

12.    Recombine Surface{1};

Построив сетку (Mesh->2D), вы увидите следующее:

Как видно, в разбиении присутствуют как четырехугольные элементы, так и треугольные. Однако так происходит только если вы рекомбинируете неструктурированную (нерегулярную) треугольную сетку.

Структурированная сетка
Попробуем разбить область на одинаковые треугольники. Для этого заменим последнюю строку .geo файла (где мы определяли рекомбинированную поверхность) на следующую:

12.    Transfinite Surface{1};

Построив сетку (Mesh->2D), вы увидите следующее:

При этом мелкость разбиения определяется параметром cl, с которым заданы точки области. Обратите внимание, что вы получите регулярную сетку только в том случае, если для всех точек области будет задана одинаковая характеристическая длина. Для области, заданной с различными значениями cl, трансфинитный алгоритм может и вовсе не сработать (а может и сработать - это как повезет).
Теперь рекомбинируем полученную сетку. Так же как и раньше добавим в конец .geo файла строку

13.    Recombine Surface{1};

Новая сетка имеет вид:

Итак, мало того, что наша сетка состоит только из четырехугольников, так они все еще и прямоугольники. Кстати, даже если вы зададите различные значения cl для точек области, после применения трансфинитного алгоритма (если он сработает) рекомбинирование все равно полностью избавит ваше разбиение от треугольников. Конечно, в этом случае вы не получите прямоугольную сетку, но может вам и четырехугольников достаточно. Зато вы можете локально мельчить сетку (иногда). Для тех, кто хочет мельчить сетку всегда и/или получать прямоугольники - следующий раздел.

Локальное измельчение прямоугольной сетки
Для того, чтобы измельчить (или наоборот - загрубить) прямоугольную сетку, нужно применить трансфинитный алгоритм не к поверхности, а к линиям. Приведу весь текст .geo файла целиком (скачать этот файл можно здесь):

1.    cl = 0.1;
2.    n = 15;
3.    k = 10;
4.    t = 1; // 0 for Progression, 1 for Bump


5.    Point(1) = {0, 0, 0, cl};
6.    Point(2) = {1, 0, 0, cl};
7.    Point(3) = {1, 1, 0, cl};
8.    Point(4) = {0, 1, 0, cl};


9.    Line(1) = {1, 2};
10.    Line(2) = {2, 3};
11.    Line(3) = {3, 4};
12.    Line(4) = {4, 1};


13.    Line Loop(5) = {1, 2, 3, 4};
14.    Plane Surface(1) = {5};


15.    If (t == 0)
16.      Transfinite Line{1} = n Using Progression k;
17.      Transfinite Line{2} = n Using Progression k;
18.      Transfinite Line{3} = n Using Progression 1/k;
19.      Transfinite Line{4} = n Using Progression 1/k;
20.    EndIf


21.    If (t == 1)
22.      Transfinite Line{1, 2, 3, 4} = n Using Bump k;
23.    EndIf


24.    Transfinite Surface(1) = {1, 2, 3, 4};
25.    Recombine Surface{1};

строки 15-23: Для того, чтобы получить прямоугольную сетку, необходимо разбить линии, ограничивающие поверхность, одномерным трансфинитным алгоритмом. Для этого необходимо указать эти линии с ключевым словом Transfinite и количеством точек, участвующих в разбиении. Формат команды такой: Transfinite Line{номера существующих линий через запятую} = количество точек <опционально Using Progression | Bump число>;. Опции Using Progression и Using Bump используются для сгущения точек к одному из краев линии (в случае Progression) или к середине линии (в случае Bump). При этом число, указанное после слова Progression | Bump, означает отношение длины следующего отрезка линии к длине предыдущего (примечание: почему то в случае Bump это не совсем так). В качестве иллюстрации приведем сетки, полученные при значениях параметров k = 1.2, t = 0 и k = 10, t = 1.

Следует отметить также, что теперь характеристическая длина не оказывает никакого влияния на мелкость сетки - все задается количеством точек (параметр n в скрипте).
строка 24: Вообще говоря, поверхность, которую планируется разбить трансфинитным алгоритмом, нужно определять именно так. Номера 1, 2, 3 и 4 - это номера точек, образующих углы области. Если эти номера не указывать, Gmsh автоматически их определит. Если после разбиения поверхности на регулярные треугольники не планируется рекомбинировать сетку, то можно указать направление ориентации треугольников с помощью ключевых слов Left | Right | Alternate. То есть полностью команда будет иметь вид: Transfinite Surface(1) = {1, 2, 3, 4} Left;. В качестве иллюстрации - регулярная треугольная сетка, полученная с каждым из этих параметров в порядке - Left, Right, Alternate: